plugins {
    java
    id("com.gradleup.shadow") version "9.0.2"
}

group = "us.tss3.boatparty"
version = "1.0.0"

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(25))
    }
}

repositories {
    mavenCentral()
    maven("https://repo.papermc.io/repository/maven-public/")
}

dependencies {
    compileOnly("io.papermc.paper:paper-api:26.2.build.111-stable")

    implementation("com.zaxxer:HikariCP:7.1.0")
    implementation("com.mysql:mysql-connector-j:26.7.0")
}

tasks {
    compileJava {
        options.encoding = "UTF-8"
        options.release.set(25)
    }

    processResources {
        filesMatching("plugin.yml") {
            expand("version" to project.version)
        }
    }

    shadowJar {
        archiveClassifier.set("")
        archiveBaseName.set("BoatParty")

        relocate("com.zaxxer.hikari", "us.tss3.boatparty.libs.hikari")
        relocate("com.mysql", "us.tss3.boatparty.libs.mysql")

        minimize {
            exclude(dependency("com.mysql:mysql-connector-j:.*"))
        }
    }

    build {
        dependsOn(shadowJar)
    }
}