BlockParty/build.gradle

plugins {
    id 'java'
    id 'com.gradleup.shadow' version '8.3.5'
}

group = 'us.tss3'
version = '1.0.0'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

repositories {
    mavenCentral()
    maven { url = 'https://repo.papermc.io/repository/maven-public/' }
    maven { url = 'https://repo.extendedclip.com/content/repositories/placeholderapi/' }
}

dependencies {
    compileOnly 'io.papermc.paper:paper-api:1.21.4-R0.1-SNAPSHOT'
    compileOnly 'me.clip:placeholderapi:2.11.6'
    implementation 'org.xerial:sqlite-jdbc:3.47.1.0'

    testImplementation platform('org.junit:junit-bom:5.11.3')
    testImplementation 'org.junit.jupiter:junit-jupiter'
}

def targetJavaVersion = 21
tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
    options.release.set(targetJavaVersion)
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}

shadowJar {
    archiveClassifier.set('')
    archiveBaseName.set('BlockParty')
    relocate 'org.sqlite', 'us.tss3.blockparty.libs.sqlite'
}

test {
    useJUnitPlatform()
}

build {
    dependsOn shadowJar
}